正在用的一些宏(悬停窃取/解诅咒宏更新)_魔兽世界台服站_魔兽世界大灾变_浩劫与重生

WOW多年来，对宏命令做出了了简单的研究探索，好用的不敢独食，在这里分享给大家：
由于我用的是英文客户端，所以宏里面的技能名都是英文，之所以没有改成中文是因为我不知道其对应的准确的中文名，不过每个宏后面都有大概的中英文对照表....
ps.认为宏没用乃至会降低操作水平的，请迅速关掉此页面，防止对您造成的不适反应。

==非战斗宏==
说明：我的alt键设为鼠标侧键，所以下面可能会出现多一些的带[mod]的组合键位命令

1.排冬握宏
/*冬握湖开始前15分钟，可以在副本或战场外任意地点加入冬握湖的队列*/
/run BattlefieldMgrQueueRequest(1)

2.焦点/目标切换宏
/*焦点设为目标且目标为焦点，用于华尔琪双子战/竞技场转集火*/
/target [target=focus]
/targetlasttarget
/focus
/targetlasttarget
说明：竞技场里面我很少用到，只在TOC老4双子战用到

3.坐下/吃喝宏
/*不加组合键(shift/alt/ctrl)就地坐下，加alt就吃喝，加shift则做面包*/
/sit
/use [modifier:alt]Conjured Mana Strudel
/use [modifier:alt]Candy Corn
/cast [modifier:shift]Conjure Refreshment
说明：复活节的棒棒糖、糖块，圣诞节的蛋糕，其回蓝回血的效果只占用回血效果的buff位置，可以和喝水buff共存，回蓝非常快堪比唤醒(圣诞节蛋糕)
技能名对照表：
Conjured Mana Strudel-幻化魔法点心
Candy Corn-糖块
Conjure Refreshment-幻化食物

4.探矿宏
/*一键无脑探矿*/
/cast Prospecting
/use Saronite Ore
说明：可以加入多个/use XXX来探多种矿，也可以用于附魔拆珠宝做的戒指项链
技能名对照表：
Saronite Ore-萨隆邪铁矿

==奥法战斗宏==

我从风暴前夕开始玩PVP，天赋用的是奥火(风暴前夕)-奥火(TBC)-奥/冰(脑残前夕)-奥(国服S7)
认为奥法无脑没有技术含量的的可以跳过这个部分
不过如果仔细看看你会发现其中大多宏经过简单修改可以运用于冰法

0.奥冲宏
/*出冰箱解除隐身，，选定鼠标指向目标，如果没目标且在战斗外则自动选择一个敌对目标；如果猎人假死丢失目标则重新选定猎人，加shift则灼烧(用于奥系被打断后)，加alt是1级冰箭(用于上致死)，什么都不按则在没有读奥弹的时候读奥冲*/
/cancelAura Ice Block
/cancelAura Invisibility
/Target [target=mouseover,harm]
/targetenemy [nocombat,noharm]
/targetlasttarget [noharm]
/cast [modifier:shift]Scorch
/cast [modifier:alt]Frostbolt(Rank 1)
/cast [nochanneling:Arcane Missiles]Arcane Blast
技能名对照：
Ice Block-冰箱
Invisibility-隐身
Scorch-灼烧
Frostbolt-冰箭
Arcane Missiles-奥弹
Arcane Blast-奥冲

1.气定奥冲宏
/*目标为敌对则气定奥冲，按alt+宏则魔杖输出*/
/cast [nomod,harm]Presence of Mind
/cast [modifier:alt]Shoot
/cast Arcane Blast
说明：如果将气定奥冲单独放一个键位，则会方便很多
技能名对照表：
Presence of Mind-气定
Shoot-魔杖射击
Arcane Blast-奥冲

2.气定焦点羊
/*焦点为敌对单位，则气定羊，最好按两下*/
/cast [target=focus,harm]Presence of Mind
/cast [mod,target=focus,harm]Polymorph(Turtle);Polymorph(Turtle)
说明：我的目标羊/目标气定羊/焦点羊/焦点气定羊都会变不同的动物，因为类似，气定羊和焦点羊宏就略去了
技能名对照表：
Polymorph(Turtle)-变海龟术

3.减速宏
/*按住ctrl则抓贼，按照鼠标目标-当前目标-自动获取目标的顺序放减速，目标猎人假死丢失目标，则选猎人*/
/cleartarget [modifier:ctrl]
/cast [modifier:shift,target=focus]slow
/Target [nomod,target=mouseover]
/TargetLastTarget [noharm]
/Targetenemy [noharm][dead]
/cast [harm]Slow
说明：常配合暴风雪砸贼+减速贼(在贼可以选定但肉眼不可见的时候就可以选中并减速)
按ctrl狂按则不断清除目标-选定目标减速。一般用于抓贼

==冰法战斗宏==

1.极冷宏
/*极冷前用掉冰脉且深结目标*/
/cast Icy Veins
/cast [target=focus]Deep Freeze
/cast Cold Snap
/script PetDismiss()
技能名对照表：
Icy Veins-冰脉
Deep Freeze-深结
Cold Snap-急冷

==通用战斗宏==

1.反制宏
/*出冰箱且打断当前施法，对鼠标目标-当前目标施放法术反制*/
/stopcasting
/cancelAura Ice Block
/cast [target=mouseover,exists,harm]Counterspell
/cast Counterspell
说明：鼠标指向宏的大多功能是指向插件里面的敌对框体、而非真正的屏幕上的目标
技能名对照表：
Ice Block-冰箱
Counterspell-反制

2.冰箱宏
/*进冰箱，狂按不会出冰箱*/
/stopcasting
/cast !Ice Block
说明：出冰箱的功能绑定在奥冲宏里面

3.暴风雪宏
/*按一下出定位圈，狂按定位圈不会消失*/
/cast [nomod]!blizzard
技能名对照表：
blizzard-暴风雪

4.焦点变羊宏
/*如果没有焦点，则将目标设为焦点并变羊；如果有焦点，则变焦点;如果按下shift/alt/ctrl则将当前目标设为焦点且变羊*/
/clearfocus [target=focus, dead]
/focus [target=focus, noexists]
/focus [mod]
/cast [target=focus]Polymorph
技能名对照表：
Polymorph-变羊术

5.保命宏
/*吃糖+战斗大师*/
/use 14
/use Fel Healthstone
/use [mod]Mana Sapphire
/cast [mod]Mana Shield
说明：战斗大师放在上面的饰物栏，14可以换成战斗大师的名字

6.火冲宏
/*如不加组合键，则按鼠标指向目标-当前目标顺序放火冲，按alt对焦点火冲，用于加了冲击天赋的奥/火法或者CTM的加了冲击天赋的各种法师，方便使用火冲击晕进行打断/控制/防御/爆发*/
/stopcasting [nomod]
/cast [nomod,target=mouseover,harm]Fire Blast;[nomod]Fire Blast
/cast [modifier:alt,target=focus]Fire Blast

7.闪现宏
/*打断施法并闪现，结合shift组合键火箭鞋*/
/stopcasting
/cast [modifier:shift]Sandals of the Silver Magus
/cast [nomod]Blink
/stopmacro [noharm]
说明：我的PVE鞋附魔火箭鞋，PVP鞋附魔海象人的活力
技能名对照表：
Sandals of the Silver Magus-白银魔导师的便鞋
Blink-闪现

8.解除诅咒/法术窃取宏终于弄好了
/*如果目标是友军则解除诅咒，如果是敌对则法术窃取，按下alt组合键给自己解诅咒，按下shift是偷焦点目标法术，常用于TOC老2*/
/stopcasting
/cast [modifier:alt,target=player]Remove Curse
/cast [modifier:shift,target=focus]Spellsteal
/cast [nomod,target=mouseover,help]Remove Curse
/cast [nomod,target=target,help]Remove Curse
/cast [nomod,target=mouseover,harm]Spellsteal;Spellsteal
255个字符一个不差...中文客户端的话，可以省掉一些字符
说明：已经经过改进，可以作用于鼠标悬停目标了
技能名对照表：
Remove Curse-解除诅咒
Spellsteal-法术窃取
鼠标指向偷取(此时没有目标，鼠标悬停敌人)-提示没有可偷取QQ截图没有鼠标指针，就用红箭头代替

鼠标指向驱散(敌对目标，鼠标悬停自己头像)-提示没有可驱散

目标偷取(敌对目标，鼠标无悬停)-提示没有可偷取

目标驱散(友善目标，鼠标无悬停)-提示没有可驱散

9.buff宏
/*按alt则加法术抑制，无组合键是奥术智力，shift组合键是专注魔法，并且会给目标密语提示给了专注*/
/cast [modifier:alt]Dampen Magic
/cast [nomod]Arcane Intellect
/cast [modifier:shift]Focus Magic
/stopmacro [noexists]
/run if(CheckInteractDistance("target",1))==1 then SendChatMessage("你获得了我的<专注魔法>!","whisper",nil,UnitName("target")) end
说明：如果你给其他人加智力/魔法抑制也会提示给了专注魔法，暂时不知道怎么解决。不过由于我加智力一直是群体智力，魔法抑制也是1级的。所以不常遇到谎报军情这个问题
技能名对照表：
Dampen Magic-魔法抑制
Arcane Intellect-奥术智力
Focus Magic-专注魔法

10.隐身宏
/*使用法力宝石，打断当前施法，且隐身，狂按不会出隐身，且水宝宝停止跟随主人*/
/use Mana Sapphire
/stopcasting
/cast !Invisibility
/petstay
说明：一般隐身时候蓝都不是满的(尤其对于奥法)；对于冰法，水宝宝停止跟随是为了防止暴露主人行踪

11.坐骑宏
/*将镜头最大设为50,并且给自己上缓落，如果能飞则上飞行坐骑，不能飞或者按任一组合键上陆地坐骑*/
/script SetCVar("cameraDistanceMax", 500)
/cast [nocombat,target=player]slow fall
/use [nocombat,outdoors,flyable,nomod]Time-Lost Proto-Drake;Mekgineer's Chopper
技能名对照表：
slow fall-缓落
Time-Lost Proto-Drake-飞行坐骑的名字
Mekgineer's Chopper-陆地坐骑的名字

12.变形术宏
/*如果没有目标则选中目标变兔子，贼如果章解消失按宏则出现暴风雪的定位圈，狂按圈不会消失，加shift且目标是敌对则冰脉变兔子*/
/targetenemy [noharm][dead]
/cast [modifier:shift,harm]Icy Vein
/cast [harm,nodead]Polymorph(Rabbit);!Blizzard
说明：我的目标/焦点目标/气定目标/气定焦点目标变形术分别是4个按键
技能名对照表：
Icy Vein-冰脉