增强宏
Code:
#showtooltip
/dismount
/cancelform [form]
/petattack [pet]
/startattack
/cast Stormstrike
上宏基本涵盖了开打时所有要做的动作。解散坐骑、还原人形、自动攻击、宠物攻击，应有尽有！风暴打击(Stormstrike)可以换成熔岩猛击(Lava Lash)。
Code:
#showtooltip
/startattack
/cast [mod] Flame Shock
/castsequence [nomod] reset=combat/8 Unleash Elements, Flame Shock
连续施法宏。将释放元素(Unleash Elements)和烈焰震击(Flame Shock)整合，但是仅有在你拥有放火的buff时才能施放火震。辅助键用来直接施放火震。可以间接用来检测持续8秒的放火buff。
Code:
/cast [@none, nomod] Windfury Weapon; [@none, mod:shift] Flametongue Weapon; [@none, mod:ctrl] Frostbrand Weapon; [@none, mod:alt] Earthliving Weapon
/use [nomod] 16; 17
/click StaticPopup1Button1
简单武器附魔宏，根据辅助键改变附魔效果。默认：主手风怒。Shift：副手火舌。Ctrl：副手冰封。Alt：副手打的生命。来自Matuk。
Code:
#showtooltip
/Cast [nopet] Feral Spirit; [] Spirit Walk
/use [nopet] 14
整合宏。一键野性之魂(Feral Spirit)并开啓幽魂步(Spirit Walk)。开始下方的饰品。
Code:
#showtooltip
/Cast [nopet] Feral Spirit; [mod, @focus][] Bash
整合宏。一键野性之魂(Feral Spirit)。辅助键用来对焦点使用重击(Bash)，不然就重击当前目标。
Code:
#showtooltip
/Cast [nopet] Feral Spirit; [mod, pet] Bash; [] Spirit Walk
/use [nopet] 14
整合宏。整合了上述两个宏，包括开啓饰品。默认施放幽魂步，辅助键用来施放重击。
Code:
/petattack [mod, @target][@focus][]
如果有焦点，命令你的宠物攻击焦点，不然就攻击当前目标。辅助键用来无视焦点直接攻击当前目标。
Code:
/run if not oldHasPetUI then oldHasPetUI = HasPetUI; HasPetUI = function() return true, false; end end
解锁你的“宠物”子页，让你能够看到两只狼的属性。与上述宠物宏绑定有惊喜。
元素宏
Code:
#showtooltip
/cast !Earthquake
移除由於多次点击造成的选择圈出现消失出现消失出现消失出现消失出现消失出现消失出现消失出现消失出现消失……
Code:
/cast Elemental Mastery
/cast Lightning Bolt
Code:
/cast Elemental Mastery
/cast Lava Burst
爆发宏。开啓元素精通(Elemental Mystery)并施放Nuke。可以加入饰品宏命令。
恢复宏
Code:
#showtooltip
/cast [@focus, help, nodead][@mouseover, help, nodead][] Earth Shield
/stopmacro [@focus, help, nodead]
/focus [@mouseover, help, nodead][]
对当前友善焦点目标施放大地之盾(Earth Shield)。如果你没有焦点，对鼠标滑过目标或者当前目标施放大地盾并将其作为新焦点。
Code:
#showtooltip
/cast !Healing Rain
移除由於多次点击造成的选择圈出现消失出现消失出现消失出现消失出现消失出现消失出现消失出现消失出现消失……
Code:
/stopcasting
/cast Nature's Swiftness
/cast Greater Healing Wave
Code:
/stopcasting
/cast Nature's Swiftness
/cast !Healing Rain
救场宏。需要移动一定距离而不必顾及灵行者优雅(Spiritwalker's Grace)，瞬间拉起血綫。
Code:
#showtooltip
/cast [@mouseover, help, nodead][@player] <你的治疗技能>
鼠标治疗宏。把“你的治疗技能”改掉！
Code:
#showtooltip
/cast [@mouseovertarget, harm, nodead] Lightning Bolt
鼠标协助宏。对鼠标滑过目标的目标施放闪电箭(Lightning Bolt)回蓝(如果点出了大地灵流(Telluric Currents)天赋)——你的鼠标应该大部分时间都是在自己人身上的。用这个宏，就不必考虑不小心的问题了。dd和坦一般都会把目标停在想干掉的目标身上吧……？
Code:
#showtooltip
/cast [@focus,harm,nodead][@target,exists] Lightning Bolt
鼠标协助宏。用途多样，不过需要设置焦点。
Code:
#showtooltip
/cast [@mouseovertarget, harm, nodead] <你的震击法术>
Code:
#showtooltip
/cast [@focus,harm,nodead][@target,exists] <你的震击法术>
用途多变，适用於点出心领神会(Focused Insight)的场合。把“你的震击法术”换掉！
